Cara Penginstalasi Shield Lora di ESP32
Bagaimana cara menginstal Shield Lora pada ESP32???
Langkah awal yang harus di lakukan yaitu menhubungkan PIN dari ESP32 ke Shield Lora menggunakan kabel jumper, untuk pin yang harus di hubungkan dapat di lihat pada gambaar di bawah:
Lalu untuk langkah selanjutnya kita perlu menginstalasi Library Lora
link library : https://github.com/mcci-catena
Saat Anda mengklik tautan, halaman yang muncul menampilkan kotak teks dengan opsi untuk menampilkan kode. Cukup tekan tombol berwarna hijau yang bertuliskan <> code untuk melihat kode yang tersembunyi di dalamnya.
Setelah proses unduhan selesai, Anda perlu membuka aplikasi Arduino.
buka bagian sketch> include Library. Sehingga menampilkan seperti gambar di bawah
Langkah berikutnya adalah menambahkan library yang sudah Anda unduh dengan memilih opsi "Add .ZIP Library..." dan memilih file library yang telah diunduh. Setelah itu, buka menu "File" dan pilih "Examples". Anda akan melihat modul yang sudah terpasang, seperti yang ditunjukkan dalam gambar di bawah ini.
Sebelum mulai menulis kode, ada langkah konfigurasi yang perlu dilakukan terlebih dahulu, seperti menentukan frekuensi, jenis modul LoRa yang digunakan, dan sebagainya. Proses ini melibatkan akses ke file pada laptop Anda yang terletak di direktori `Documents/Arduino/libraries/MCCI_LoRaWAN_LMIC_library/project_config. Di dalam direktori ini, Anda akan menemukan file ` lmic_project_config.h `, seperti yang ditunjukkan dalam gambar di bawah ini.
Setelah membuka file tersebut, Anda akan melihat konfigurasi yang perlu Anda atur, termasuk frekuensi, mirip dengan yang ditampilkan dalam gambar di bawah ini.
code full configurasinya
Setelah selesai mengatur pengaturan, pastikan untuk menyimpan perubahan tersebut di lokasi yang sama.
Sebagai informasi tambahan, LoRa memiliki mekanisme keamanan sendiri dalam komunikasi, yaitu ABP (Activation by Personalization) dan OTAA (Over-the-Air Activation). Konfigurasi keamanan ini biasanya dilakukan di server, seperti yang disediakan oleh [Thethings network](https://eu1.cloud.thethings.network/console/). Untuk keamanan OTAA, Anda akan membutuhkan 3 kunci: APPEUI, DEVEUI, dan APPKEY.
Setelah itu, buka contoh kode dengan memilih MCCI LoRaWAN lmic library dari daftar contoh. Pilih contoh bernama "ttn-otaa", seperti yang ditunjukkan dalam gambar di bawah ini.
setelah itu maka akan keluar kode :
/*******************************************************************************
* Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
* Copyright (c) 2018 Terry Moore, MCCI
*
* Permission is hereby granted, free of charge, to anyone
* obtaining a copy of this document and accompanying files,
* to do whatever they want with them without any restriction,
* including, but not limited to, copying, modification and redistribution.
* NO WARRANTY OF ANY KIND IS PROVIDED.
*
* This example sends a valid LoRaWAN packet with payload "Hello,
* world!", using frequency and encryption settings matching those of
* the The Things Network.
*
* This uses OTAA (Over-the-air activation), where where a DevEUI and
* application key is configured, which are used in an over-the-air
* activation procedure where a DevAddr and session keys are
* assigned/generated for use with all further communication.
*
* Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in
* g1, 0.1% in g2), but not the TTN fair usage policy (which is probably
* violated by this sketch when left running for longer)!
* To use this sketch, first register your application and device with
* the things network, to set or generate an AppEUI, DevEUI and AppKey.
* Multiple devices can use the same AppEUI, but each device has its own
* DevEUI and AppKey.
*
* Do not forget to define the radio type correctly in
* arduino-lmic/project_config/lmic_project_config.h or from your BOARDS.txt.
*
*******************************************************************************/
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
//
// For normal use, we require that you edit the sketch to replace FILLMEIN
// with values assigned by the TTN console. However, for regression tests,
// we want to be able to compile these scripts. The regression tests define
// COMPILE_REGRESSION_TEST, and in that case we define FILLMEIN to a non-
// working but innocuous value.
//
#ifdef COMPILE_REGRESSION_TEST
# define FILLMEIN 0
#else
# warning "You must replace the values marked FILLMEIN with real values from the TTN control panel!"
# define FILLMEIN (#dont edit this, edit the lines that use FILLMEIN)
#endif
// This EUI must be in little-endian format, so least-significant-byte
// first. When copying an EUI from ttnctl output, this means to reverse
// the bytes. For TTN issued EUIs the last bytes should be 0xD5, 0xB3,
// 0x70.
static const u1_t PROGMEM APPEUI[8] = {0x01, 0x01, 0x00, 0x00, 0x00, 0x0, 0x00, 0x00};
void os_getArtEui(u1_t* buf) { memcpy_P(buf, APPEUI, 8); }
// LSB
static const u1_t PROGMEM DEVEUI[8] = {0xae, 0xcf, 0xef, 0xbb, 0xcd, 0x1d, 0xc3, 0x48};
void os_getDevEui(u1_t* buf) { memcpy_P(buf, DEVEUI, 8); }
//MSB
static const u1_t PROGMEM APPKEY[16] = {0x9a, 0x19, 0x93, 0xcc, 0xc4, 0x78, 0xbc, 0x8e, 0x6d, 0x4b, 0xe5, 0x99, 0xab, 0x16, 0xe5, 0x06};
void os_getDevKey(u1_t* buf) { memcpy_P(buf, APPKEY, 16); }
static uint8_t mydata[] = "Akhirnya Bisa";
static osjob_t sendjob;
// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 30;
// Pin mapping lora Sheld
const lmic_pinmap lmic_pins = {
.nss = 15,
.rxtx = LMIC_UNUSED_PIN,
.rst = 13,
.dio = {12, 14, 26},
};
void printHex2(unsigned v) {
v &= 0xff;
if (v < 16)
Serial.print('0');
Serial.print(v, HEX);
}
void onEvent (ev_t ev) {
Serial.print(os_getTime());
Serial.print(": ");
switch(ev) {
case EV_SCAN_TIMEOUT:
Serial.println(F("EV_SCAN_TIMEOUT"));
break;
case EV_BEACON_FOUND:
Serial.println(F("EV_BEACON_FOUND"));
break;
case EV_BEACON_MISSED:
Serial.println(F("EV_BEACON_MISSED"));
break;
case EV_BEACON_TRACKED:
Serial.println(F("EV_BEACON_TRACKED"));
break;
case EV_JOINING:
Serial.println(F("EV_JOINING"));
break;
case EV_JOINED:
Serial.println(F("EV_JOINED"));
{
u4_t netid = 0;
devaddr_t devaddr = 0;
u1_t nwkKey[16];
u1_t artKey[16];
LMIC_getSessionKeys(&netid, &devaddr, nwkKey, artKey);
Serial.print("netid: ");
Serial.println(netid, DEC);
Serial.print("devaddr: ");
Serial.println(devaddr, HEX);
Serial.print("AppSKey: ");
for (size_t i=0; i<sizeof(artKey); ++i) {
if (i != 0)
Serial.print("-");
printHex2(artKey[i]);
}
Serial.println("");
Serial.print("NwkSKey: ");
for (size_t i=0; i<sizeof(nwkKey); ++i) {
if (i != 0)
Serial.print("-");
printHex2(nwkKey[i]);
}
Serial.println();
}
// Disable link check validation (automatically enabled
// during join, but because slow data rates change max TX
// size, we don't use it in this example.
LMIC_setLinkCheckMode(0);
break;
/*
|| This event is defined but not used in the code. No
|| point in wasting codespace on it.
||
|| case EV_RFU1:
|| Serial.println(F("EV_RFU1"));
|| break;
*/
case EV_JOIN_FAILED:
Serial.println(F("EV_JOIN_FAILED"));
break;
case EV_REJOIN_FAILED:
Serial.println(F("EV_REJOIN_FAILED"));
break;
case EV_TXCOMPLETE:
Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
if (LMIC.txrxFlags & TXRX_ACK)
Serial.println(F("Received ack"));
if (LMIC.dataLen) {
Serial.print(F("Received "));
Serial.print(LMIC.dataLen);
Serial.println(F(" bytes of payload"));
}
// Schedule next transmission
os_setTimedCallback(&sendjob, os_getTime()+sec2osticks(TX_INTERVAL), do_send);
break;
case EV_LOST_TSYNC:
Serial.println(F("EV_LOST_TSYNC"));
break;
case EV_RESET:
Serial.println(F("EV_RESET"));
break;
case EV_RXCOMPLETE:
// data received in ping slot
Serial.println(F("EV_RXCOMPLETE"));
break;
case EV_LINK_DEAD:
Serial.println(F("EV_LINK_DEAD"));
break;
case EV_LINK_ALIVE:
Serial.println(F("EV_LINK_ALIVE"));
break;
/*
|| This event is defined but not used in the code. No
|| point in wasting codespace on it.
||
|| case EV_SCAN_FOUND:
|| Serial.println(F("EV_SCAN_FOUND"));
|| break;
*/
case EV_TXSTART:
Serial.println(F("EV_TXSTART"));
break;
case EV_TXCANCELED:
Serial.println(F("EV_TXCANCELED"));
break;
case EV_RXSTART:
/* do not print anything -- it wrecks timing */
break;
case EV_JOIN_TXCOMPLETE:
Serial.println(F("EV_JOIN_TXCOMPLETE: no JoinAccept"));
break;
default:
Serial.print(F("Unknown event: "));
Serial.println((unsigned) ev);
break;
}
}
void do_send(osjob_t* j){
// Check if there is not a current TX/RX job running
if (LMIC.opmode & OP_TXRXPEND) {
Serial.println(F("OP_TXRXPEND, not sending"));
} else {
// Prepare upstream data transmission at the next possible time.
LMIC_setTxData2(1, mydata, sizeof(mydata)-1, 0);
Serial.println(F("Packet queued"));
}
// Next TX is scheduled after TX_COMPLETE event.
}
void setup() {
Serial.begin(9600);
Serial.println(F("Starting"));
#ifdef VCC_ENABLE
// For Pinoccio Scout boards
pinMode(VCC_ENABLE, OUTPUT);
digitalWrite(VCC_ENABLE, HIGH);
delay(1000);
#endif
// LMIC init
os_init();
// Reset the MAC state. Session and pending data transfers will be discarded.
LMIC_reset();
// Start job (sending automatically starts OTAA too)
do_send(&sendjob);
}
void loop() {
os_runloop_once();
}
Kalian perlu mengubah pin mapping dalam kode sesuai dengan pin yang sudah kalian pasang pada ESP32. Untuk pin NSS, kalian telah memasangnya pada port 15 pada ESP32.
Dan kalian perlu memasukkan 3 kode tersebut pada.
static const u1_t PROGMEM APPEUI[8] = {0x01, 0x01, 0x00, 0x00, 0x00, 0x0, 0x00, 0x00};
void os_getArtEui(u1_t* buf) { memcpy_P(buf, APPEUI, 8); }
// LSB
static const u1_t PROGMEM DEVEUI[8] = {0xae, 0xcf, 0xef, 0xbb, 0xcd, 0x1d, 0xc3, 0x48};
void os_getDevEui(u1_t* buf) { memcpy_P(buf, DEVEUI, 8); }
//MSB
static const u1_t PROGMEM APPKEY[16] = {0x9a, 0x19, 0x93, 0xcc, 0xc4, 0x78, 0xbc, 0x8e, 0x6d, 0x4b, 0xe5, 0x99, 0xab, 0x16, 0xe5, 0x06};
void os_getDevKey(u1_t* buf) { memcpy_P(buf, APPKEY, 16); }
Pada bagian FILLMEIN, gantilah dengan kunci yang kalian peroleh dari server dalam bentuk array hex, misalnya: 0x01, 0x01, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00.
Komentar
Posting Komentar