Penginstalan Konfigurasi Lora Gateway Tersambung Ke MQTT Broker
Konfigurasi Lora Gateway Ke MQTT Broker
Teknologi nirkabel yang semakin populer untuk aplikasi IoT adalah LoRa (Long Range). Dalam ekosistem LoRa, LoRa Gateway memiliki peran vital sebagai titik akses, menghubungkan perangkat LoRa yang tersebar luas dan mengumpulkan data dari mereka untuk diteruskan ke infrastruktur jaringan. Di sisi lain, MQTT (Message Queuing Telemetry Transport) adalah protokol komunikasi yang ringan dan berfokus pada model pub/sub (publish-subscribe). Ini sering dipakai dalam konteks IoT untuk mengirimkan data dari perangkat ke server atau antar perangkat dan aplikasi.
Langkah-langkah untuk mengatur LoRa Gateway agar bisa mengirim pesan ke MQTT Broker adalah sebagai berikut:
1. Periksa terlebih dahulu bahwa Anda memiliki akses ke LoRa Gateway yang mendukung protokol MQTT dan koneksi internet yang stabil.
2. Install dan konfigurasi MQTT Broker seperti MQTT Explorer, yang bisa diakses melalui situs https://mqtt-explorer.com/.
3. Buka Arduino dan atur "Board dan Port" yang akan digunakan sesuai dengan kebutuhan Anda.
4. Lanjutkan dengan memasang perpustakaan LoRa untuk ESP32 di Arduino IDE. Caranya adalah dengan membuka menu "Sketch", lalu pilih "Include Library", dan akhirnya pilih "MCCI LoRaWAN LMIC Library". Jika perpustakaan tidak tersedia, Anda dapat mengunduhnya dari situs GitHub di https://github.com/mcci-catena.
5.Untuk memulai komunikasi LoRa antara ESP32 dan modul LoRa menggunakan Arduino IDE, langkah pertama adalah menulis kode program yang mencakup inisialisasi perangkat. Selanjutnya, Anda perlu mengonfigurasi parameter LoRa seperti frekuensi, faktor spreading, bandwidth, dan coding rate. Terakhir, tambahkan kode untuk mengirim pesan melalui protokol LoRa. Berikut adalah contoh kode yang bisa Anda gunakan:
/*******************************************************************************
* Copyright (c) 2015 Thomas Telkamp and Matthijs Kooijman
* Copyright (c) 2018 Terry Moore, MCCI
*
* Permission is hereby granted, free of charge, to anyone
* obtaining a copy of this document and accompanying files,
* to do whatever they want with them without any restriction,
* including, but not limited to, copying, modification and redistribution.
* NO WARRANTY OF ANY KIND IS PROVIDED.
*
* This example sends a valid LoRaWAN packet with payload "Hello,
* world!", using frequency and encryption settings matching those of
* the The Things Network.
*
* This uses OTAA (Over-the-air activation), where where a DevEUI and
* application key is configured, which are used in an over-the-air
* activation procedure where a DevAddr and session keys are
* assigned/generated for use with all further communication.
*
* Note: LoRaWAN per sub-band duty-cycle limitation is enforced (1% in
* g1, 0.1% in g2), but not the TTN fair usage policy (which is probably
* violated by this sketch when left running for longer)!
* To use this sketch, first register your application and device with
* the things network, to set or generate an AppEUI, DevEUI and AppKey.
* Multiple devices can use the same AppEUI, but each device has its own
* DevEUI and AppKey.
*
* Do not forget to define the radio type correctly in
* arduino-lmic/project_config/lmic_project_config.h or from your BOARDS.txt.
*
*******************************************************************************/
#include <lmic.h>
#include <hal/hal.h>
#include <SPI.h>
//
// For normal use, we require that you edit the sketch to replace FILLMEIN
// with values assigned by the TTN console. However, for regression tests,
// we want to be able to compile these scripts. The regression tests define
// COMPILE_REGRESSION_TEST, and in that case we define FILLMEIN to a non-
// working but innocuous value.
//
#ifdef COMPILE_REGRESSION_TEST
# define FILLMEIN 0
#else
# warning "You must replace the values marked FILLMEIN with real values from the TTN control panel!"
# define FILLMEIN (#dont edit this, edit the lines that use FILLMEIN)
#endif
// This EUI must be in little-endian format, so least-significant-byte
// first. When copying an EUI from ttnctl output, this means to reverse
// the bytes. For TTN issued EUIs the last bytes should be 0xD5, 0xB3,
// 0x70.
static const u1_t PROGMEM APPEUI[8] = {0x01, 0x01, 0x00, 0x00, 0x00, 0x0, 0x00, 0x00};
void os_getArtEui(u1_t* buf) { memcpy_P(buf, APPEUI, 8); }
// LSB
static const u1_t PROGMEM DEVEUI[8] = {0xae, 0xcf, 0xef, 0xbb, 0xcd, 0x1d, 0xc3, 0x48};
void os_getDevEui(u1_t* buf) { memcpy_P(buf, DEVEUI, 8); }
//MSB
static const u1_t PROGMEM APPKEY[16] = {0x9a, 0x19, 0x93, 0xcc, 0xc4, 0x78, 0xbc, 0x8e, 0x6d, 0x4b, 0xe5, 0x99, 0xab, 0x16, 0xe5, 0x06};
void os_getDevKey(u1_t* buf) { memcpy_P(buf, APPKEY, 16); }
static uint8_t mydata[] = "Akhirnya Bisa";
static osjob_t sendjob;
// Schedule TX every this many seconds (might become longer due to duty
// cycle limitations).
const unsigned TX_INTERVAL = 30;
// Pin mapping lora Sheld
const lmic_pinmap lmic_pins = {
.nss = 15,
.rxtx = LMIC_UNUSED_PIN,
.rst = 13,
.dio = {12, 14, 26},
};
void printHex2(unsigned v) {
v &= 0xff;
if (v < 16)
Serial.print('0');
Serial.print(v, HEX);
}
void onEvent (ev_t ev) {
Serial.print(os_getTime());
Serial.print(": ");
switch(ev) {
case EV_SCAN_TIMEOUT:
Serial.println(F("EV_SCAN_TIMEOUT"));
break;
case EV_BEACON_FOUND:
Serial.println(F("EV_BEACON_FOUND"));
break;
case EV_BEACON_MISSED:
Serial.println(F("EV_BEACON_MISSED"));
break;
case EV_BEACON_TRACKED:
Serial.println(F("EV_BEACON_TRACKED"));
break;
case EV_JOINING:
Serial.println(F("EV_JOINING"));
break;
case EV_JOINED:
Serial.println(F("EV_JOINED"));
{
u4_t netid = 0;
devaddr_t devaddr = 0;
u1_t nwkKey[16];
u1_t artKey[16];
LMIC_getSessionKeys(&netid, &devaddr, nwkKey, artKey);
Serial.print("netid: ");
Serial.println(netid, DEC);
Serial.print("devaddr: ");
Serial.println(devaddr, HEX);
Serial.print("AppSKey: ");
for (size_t i=0; i<sizeof(artKey); ++i) {
if (i != 0)
Serial.print("-");
printHex2(artKey[i]);
}
Serial.println("");
Serial.print("NwkSKey: ");
for (size_t i=0; i<sizeof(nwkKey); ++i) {
if (i != 0)
Serial.print("-");
printHex2(nwkKey[i]);
}
Serial.println();
}
// Disable link check validation (automatically enabled
// during join, but because slow data rates change max TX
// size, we don't use it in this example.
LMIC_setLinkCheckMode(0);
break;
/*
|| This event is defined but not used in the code. No
|| point in wasting codespace on it.
||
|| case EV_RFU1:
|| Serial.println(F("EV_RFU1"));
|| break;
*/
case EV_JOIN_FAILED:
Serial.println(F("EV_JOIN_FAILED"));
break;
case EV_REJOIN_FAILED:
Serial.println(F("EV_REJOIN_FAILED"));
break;
case EV_TXCOMPLETE:
Serial.println(F("EV_TXCOMPLETE (includes waiting for RX windows)"));
if (LMIC.txrxFlags & TXRX_ACK)
Serial.println(F("Received ack"));
if (LMIC.dataLen) {
Serial.print(F("Received "));
Serial.print(LMIC.dataLen);
Serial.println(F(" bytes of payload"));
}
// Schedule next transmission
os_setTimedCallback(&sendjob, os_getTime()+sec2osticks(TX_INTERVAL), do_send);
break;
case EV_LOST_TSYNC:
Serial.println(F("EV_LOST_TSYNC"));
break;
case EV_RESET:
Serial.println(F("EV_RESET"));
break;
case EV_RXCOMPLETE:
// data received in ping slot
Serial.println(F("EV_RXCOMPLETE"));
break;
case EV_LINK_DEAD:
Serial.println(F("EV_LINK_DEAD"));
break;
case EV_LINK_ALIVE:
Serial.println(F("EV_LINK_ALIVE"));
break;
/*
|| This event is defined but not used in the code. No
|| point in wasting codespace on it.
||
|| case EV_SCAN_FOUND:
|| Serial.println(F("EV_SCAN_FOUND"));
|| break;
*/
case EV_TXSTART:
Serial.println(F("EV_TXSTART"));
break;
case EV_TXCANCELED:
Serial.println(F("EV_TXCANCELED"));
break;
case EV_RXSTART:
/* do not print anything -- it wrecks timing */
break;
case EV_JOIN_TXCOMPLETE:
Serial.println(F("EV_JOIN_TXCOMPLETE: no JoinAccept"));
break;
default:
Serial.print(F("Unknown event: "));
Serial.println((unsigned) ev);
break;
}
}
void do_send(osjob_t* j){
// Check if there is not a current TX/RX job running
if (LMIC.opmode & OP_TXRXPEND) {
Serial.println(F("OP_TXRXPEND, not sending"));
} else {
// Prepare upstream data transmission at the next possible time.
LMIC_setTxData2(1, mydata, sizeof(mydata)-1, 0);
Serial.println(F("Packet queued"));
}
// Next TX is scheduled after TX_COMPLETE event.
}
void setup() {
Serial.begin(9600);
Serial.println(F("Starting"));
#ifdef VCC_ENABLE
// For Pinoccio Scout boards
pinMode(VCC_ENABLE, OUTPUT);
digitalWrite(VCC_ENABLE, HIGH);
delay(1000);
#endif
// LMIC init
os_init();
// Reset the MAC state. Session and pending data transfers will be discarded.
LMIC_reset();
// Start job (sending automatically starts OTAA too)
do_send(&sendjob);
}
void loop() {
os_runloop_once();
}
6. Untuk menyiapkan LoRa Gateway agar bisa mengirim pesan ke MQTT Broker, Anda perlu menetapkan alamat dan port MQTT Broker. Selanjutnya, tentukan topik MQTT di mana pesan dari LoRa Gateway akan dipublikasikan, dan atur pengaturan keamanan seperti nama pengguna dan kata sandi jika diperlukan oleh broker MQTT.
7. Setelah membuka Arduino IDE, langkah berikutnya adalah mengunggah kode ke ESP32 dengan menekan tombol "Upload" di Arduino IDE. Setelah itu, buka MQTT Explorer, di mana Anda akan dapat melihat pesan yang diterima pada tampilan sisi kanan.
Komentar
Posting Komentar